Initial Commit

vendor/SDL3_ttf-3.2.2/Xcode/pkg-support/resources/CMake/SDL3_ttfConfig.cmake

@@ -0,0 +1,85 @@
+# SDL3_ttf CMake configuration file:
+# This file is meant to be placed in Resources/CMake of a SDL3_ttf framework
+
+# INTERFACE_LINK_OPTIONS needs CMake 3.12
+cmake_minimum_required(VERSION 3.12...3.28)
+
+include(FeatureSummary)
+set_package_properties(SDL3_ttf PROPERTIES
+    URL "https://www.libsdl.org/projects/SDL_ttf/"
+    DESCRIPTION "Support for TrueType (.ttf) font files with Simple Directmedia Layer"
+)
+
+# Copied from `configure_package_config_file`
+macro(check_required_components _NAME)
+    foreach(comp ${${_NAME}_FIND_COMPONENTS})
+        if(NOT ${_NAME}_${comp}_FOUND)
+            if(${_NAME}_FIND_REQUIRED_${comp})
+                set(${_NAME}_FOUND FALSE)
+            endif()
+        endif()
+    endforeach()
+endmacro()
+
+set(SDL3_ttf_FOUND TRUE)
+
+set(SDLTTF_VENDORED TRUE)
+
+set(SDLTTF_HARFBUZZ TRUE)
+set(SDLTTF_FREETYPE TRUE)
+
+# Compute the installation prefix relative to this file.
+set(_sdl3_ttf_framework_path "${CMAKE_CURRENT_LIST_DIR}")                                   # > /SDL3_ttf.framework/Resources/CMake/
+get_filename_component(_sdl3_ttf_framework_path "${_sdl3_ttf_framework_path}" REALPATH)     # > /SDL3_ttf.framework/Versions/Current/Resources/CMake
+get_filename_component(_sdl3_ttf_framework_path "${_sdl3_ttf_framework_path}" REALPATH)     # > /SDL3_ttf.framework/Versions/A/Resources/CMake/
+get_filename_component(_sdl3_ttf_framework_path "${_sdl3_ttf_framework_path}" PATH)         # > /SDL3_ttf.framework/Versions/A/Resources/
+get_filename_component(_sdl3_ttf_framework_path "${_sdl3_ttf_framework_path}" PATH)         # > /SDL3_ttf.framework/Versions/A/
+get_filename_component(_sdl3_ttf_framework_path "${_sdl3_ttf_framework_path}" PATH)         # > /SDL3_ttf.framework/Versions/
+get_filename_component(_sdl3_ttf_framework_path "${_sdl3_ttf_framework_path}" PATH)         # > /SDL3_ttf.framework/
+get_filename_component(_sdl3_ttf_framework_parent_path "${_sdl3_ttf_framework_path}" PATH)  # > /
+
+# All targets are created, even when some might not be requested though COMPONENTS.
+# This is done for compatibility with CMake generated SDL3_ttf-target.cmake files.
+
+if(NOT TARGET SDL3_ttf::SDL3_ttf-shared)
+    add_library(SDL3_ttf::SDL3_ttf-shared SHARED IMPORTED)
+    set_target_properties(SDL3_ttf::SDL3_ttf-shared
+        PROPERTIES
+            FRAMEWORK "TRUE"
+            IMPORTED_LOCATION "${_sdl_ttf_framework_path}/SDL3_ttf"
+            COMPATIBLE_INTERFACE_BOOL "SDL3_SHARED"
+            INTERFACE_SDL3_SHARED "ON"
+            COMPATIBLE_INTERFACE_STRING "SDL_VERSION"
+            INTERFACE_SDL_VERSION "SDL3"
+    )
+endif()
+set(SDL3_ttf_SDL3_ttf-shared_FOUND TRUE)
+
+set(SDL3_ttf_SDL3_ttf-static_FOUND FALSE)
+
+unset(_sdl3_ttf_framework_path)
+unset(_sdl3_ttf_framework_parent_path)
+
+set(SDL3_ttf_SDL3_ttf_FOUND FALSE)
+if(SDL3_ttf_SDL3_ttf-shared_FOUND OR SDL3_ttf_SDL3_ttf-static_FOUND)
+    set(SDL3_ttf_SDL3_ttf_FOUND TRUE)
+endif()
+
+function(_sdl_create_target_alias_compat NEW_TARGET TARGET)
+    if(CMAKE_VERSION VERSION_LESS "3.18")
+        # Aliasing local targets is not supported on CMake < 3.18, so make it global.
+        add_library(${NEW_TARGET} INTERFACE IMPORTED)
+        set_target_properties(${NEW_TARGET} PROPERTIES INTERFACE_LINK_LIBRARIES "${TARGET}")
+    else()
+        add_library(${NEW_TARGET} ALIAS ${TARGET})
+    endif()
+endfunction()
+
+# Make sure SDL3_ttf::SDL3_ttf always exists
+if(NOT TARGET SDL3_ttf::SDL3_ttf)
+    if(TARGET SDL3_ttf::SDL3_ttf-shared)
+        _sdl_create_target_alias_compat(SDL3_ttf::SDL3_ttf SDL3_ttf::SDL3_ttf-shared)
+    endif()
+endif()
+
+check_required_components(SDL3_ttf)

vendor/SDL3_ttf-3.2.2/Xcode/pkg-support/resources/CMake/SDL3_ttfConfigVersion.cmake

@@ -0,0 +1,48 @@
+# based on the files generated by CMake's write_basic_package_version_file
+
+# SDL3_ttf CMake version configuration file:
+# This file is meant to be placed in Resources/CMake of a SDL3_ttf framework
+
+if(NOT EXISTS "${CMAKE_CURRENT_LIST_DIR}/../../Headers/SDL_ttf.h")
+    message(AUTHOR_WARNING "Could not find SDL_ttf.h. This script is meant to be placed in the Resources/CMake directory of SDL3_ttf.framework")
+    return()
+endif()
+
+file(READ "${CMAKE_CURRENT_LIST_DIR}/../../Headers/SDL_ttf.h" _sdl_ttf_h)
+string(REGEX MATCH "#define[ \t]+SDL_TTF_MAJOR_VERSION[ \t]+([0-9]+)" _sdl_major_re "${_sdl_ttf_h}")
+set(_sdl_major "${CMAKE_MATCH_1}")
+string(REGEX MATCH "#define[ \t]+SDL_TTF_MINOR_VERSION[ \t]+([0-9]+)" _sdl_minor_re "${_sdl_ttf_h}")
+set(_sdl_minor "${CMAKE_MATCH_1}")
+string(REGEX MATCH "#define[ \t]+SDL_TTF_MICRO_VERSION[ \t]+([0-9]+)" _sdl_micro_re "${_sdl_ttf_h}")
+set(_sdl_micro "${CMAKE_MATCH_1}")
+if(_sdl_major_re AND _sdl_minor_re AND _sdl_micro_re)
+    set(PACKAGE_VERSION "${_sdl_major}.${_sdl_minor}.${_sdl_micro}")
+else()
+    message(AUTHOR_WARNING "Could not extract version from SDL_ttf.h.")
+    return()
+endif()
+
+if(PACKAGE_FIND_VERSION_RANGE)
+    # Package version must be in the requested version range
+    if ((PACKAGE_FIND_VERSION_RANGE_MIN STREQUAL "INCLUDE" AND PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION_MIN)
+        OR ((PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "INCLUDE" AND PACKAGE_VERSION VERSION_GREATER PACKAGE_FIND_VERSION_MAX)
+        OR (PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "EXCLUDE" AND PACKAGE_VERSION VERSION_GREATER_EQUAL PACKAGE_FIND_VERSION_MAX)))
+        set(PACKAGE_VERSION_COMPATIBLE FALSE)
+    else()
+        set(PACKAGE_VERSION_COMPATIBLE TRUE)
+    endif()
+else()
+    if(PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION)
+        set(PACKAGE_VERSION_COMPATIBLE FALSE)
+    else()
+        set(PACKAGE_VERSION_COMPATIBLE TRUE)
+        if(PACKAGE_FIND_VERSION STREQUAL PACKAGE_VERSION)
+            set(PACKAGE_VERSION_EXACT TRUE)
+        endif()
+    endif()
+endif()
+
+# if the using project doesn't have CMAKE_SIZEOF_VOID_P set, fail.
+if("${CMAKE_SIZEOF_VOID_P}" STREQUAL "")
+    set(PACKAGE_VERSION_UNSUITABLE TRUE)
+endif()

vendor/SDL3_ttf-3.2.2/Xcode/pkg-support/resources/INSTALL.md

@@ -0,0 +1,37 @@
+
+# Using this package
+
+This package contains SDL_ttf built for Xcode, and includes support for macOS, iOS and tvOS.
+
+To use this package in Xcode, drag `SDL3_ttf.xcframework` into your project.
+
+To use this package in a CMake project, copy both `SDL3_ttf.xcframework` and `share` to `~/Library/Frameworks`.
+
+# Documentation
+
+An API reference and additional documentation is available at:
+
+https://wiki.libsdl.org/SDL3_ttf
+
+# Discussions
+
+## Discord
+
+You can join the official Discord server at:
+
+https://discord.com/invite/BwpFGBWsv8
+
+## Forums/mailing lists
+
+You can join SDL development discussions at:
+
+https://discourse.libsdl.org/
+
+Once you sign up, you can use the forum through the website or as a mailing list from your email client.
+
+## Announcement list
+
+You can sign up for the low traffic announcement list at:
+
+https://www.libsdl.org/mailing-list.php
+

vendor/SDL3_ttf-3.2.2/Xcode/pkg-support/resources/framework/INSTALL.md

@@ -0,0 +1,35 @@
+
+# Using this package
+
+This package contains SDL_ttf built for Xcode.
+
+To use this package in Xcode, drag `SDL3_ttf.framework` into your project.
+
+# Documentation
+
+An API reference and additional documentation is available at:
+
+https://wiki.libsdl.org/SDL3_ttf
+
+# Discussions
+
+## Discord
+
+You can join the official Discord server at:
+
+https://discord.com/invite/BwpFGBWsv8
+
+## Forums/mailing lists
+
+You can join SDL development discussions at:
+
+https://discourse.libsdl.org/
+
+Once you sign up, you can use the forum through the website or as a mailing list from your email client.
+
+## Announcement list
+
+You can sign up for the low traffic announcement list at:
+
+https://www.libsdl.org/mailing-list.php
+